home *** CD-ROM | disk | FTP | other *** search
/ Ham Radio 2000 / Ham Radio 2000.iso / ham2000 / misc / spctr3e2 / demo2.cir < prev    next >
Text File  |  1992-12-11  |  3KB  |  99 lines
  1. ** Darlington boost op-amp (from EDN May 29, 1986 pg 133 -> with minor changes)
  2.  
  3. vin 1 0 sin(0 5 10k) dc 0 ac 1
  4. vcc     11      0       15.0
  5. vee     12      0       -15.0
  6. r1      0       2       10k
  7. r2      2     out       10k
  8. r3      5       6       2k
  9. r4      5      20       33k
  10. r5     20      10       2k
  11. r6     11       7       1.2k
  12. r7     18      12       1.2k
  13. r8     14      15       1k
  14. r9     16      17       1k
  15. r10    15     out       .1
  16. r11    17     out       .1
  17. r12     1       3       5k
  18. rload out       0       8
  19. c1      2       4       39pf
  20. d1     11       6          D1N4148
  21. d2      8       9          D1N4148
  22. d3      9       4          D1N4148
  23. d4      4      13          d1n4148
  24. d5     13      19          d1n4148
  25. d6     10      12          d1n4148
  26. q1      8       5      7   q2n3906
  27. q2     19      20     18   q2n3904
  28. q3      8      14    out   q2n2222A
  29. q4     19      16    out   q2n2907A
  30. x1      3       2     11     12   4  lf156
  31. x2     11       8     15   q2n6384
  32. x3     12      19     17   q2n6649
  33. .include lf156
  34.  
  35. * Note: this next line are meaningful only in batch mode
  36. .save 1 out
  37. * Note: these next lines are meaningful only in batch mode
  38. * or when the "run" command is given in interactive mode
  39. .AC dec 15 1 100meghz
  40. .tran .5us 200us
  41. .four 10k out
  42. ***************************
  43. *  models and subcircuits *
  44. ***************************
  45. .MODEL D1N4148 D (IS=14.2P RS=4.2 N=1.7 BV=74.9 IBV=10U
  46. + CJO=1.73P VJ=.75 M=.333 TT=5.76N)
  47. *   75 Volt  .01 Amp  .004 us  Si Diode  07-08-1991
  48. **********
  49. .MODEL Q2N3906 PNP (IS=8.012404E-17 NF=1 BF=136 VAF=113 IKF=65M
  50. + ISE=800F NE=2 BR=4 NR=1 VAR=20 IKR=97.5M RE=3.63 RB=14.5
  51. + RC=1.45 XTB=1.5 CJE=11.8P CJC=8.81P TF=636P TR=95.6N)
  52. *   40 Volt  .2 Amp  250 MHz  SiPNP  Transistor  06-28-1991
  53. **********
  54. .MODEL Q2N3904 NPN (IS=4.667347E-17 NF=1 BF=238 VAF=113 IKF=65M
  55. + ISE=1.18P NE=2 BR=4 NR=1 VAR=24 IKR=97.5M RE=2.63 RB=10.5
  56. + RC=1.05 XTB=1.5 CJE=9.46P CJC=7.83P TF=530P TR=85N)
  57. *   40 Volt  .2 Amp  300 MHz  SiNPN  Transistor  06-28-1991
  58. **********
  59. .MODEL Q2N2222A NPN (IS=5.632971E-19 NF=1 BF=175 VAF=113 IKF=.4
  60. + ISE=237F NE=2 BR=4 NR=1 VAR=24 IKR=.6 RE=.963 RB=3.85
  61. + RC=.385 XTB=1.5 CJE=29.5P CJC=19.2P TF=530P TR=95.6N)
  62. *   40 Volt  .8 Amp  300 MHz  SiNPN  Transistor  06-28-1991
  63. **********
  64. .MODEL Q2N2907A PNP (IS=1.536728E-18 NF=1 BF=103 VAF=139 IKF=.5
  65. + ISE=96.0F NE=2 BR=4 NR=1 VAR=20 IKR=.75 RE=1.56 RB=6.25
  66. + RC=.625 XTB=1.5 CJE=46.0P CJC=19.2P TF=794P TR=34N)
  67. *   60 Volt  .6 Amp  200 MHz  SiPNP  Transistor  06-28-1991
  68. **********
  69. .SUBCKT Q2N6384  1 2 3
  70. *    TERMINALS:  C B E
  71. Q1 1 2 4 QPWR .1
  72. Q2 1 4 3 QPWR
  73. R1 2 4  4K
  74. R2 4 3  50
  75. D1 3 1  DSUB
  76. .MODEL QPWR NPN (IS=12P NF=1 BF=49.3 VAF=139 IKF=7.5
  77. + ISE=21.2P NE=2 BR=4 NR=1 VAR=20 IKR=11.2 RE=.115 RB=.46
  78. + RC=46M XTB=1.5 CJE=2.21N CJC=481P TF=1.34P TR=3.67U)
  79. .MODEL DSUB D (IS=12P N=1 RS=.115 BV=60 IBV=.001
  80. + CJO=481P TT=3.67U)
  81. .ENDS
  82. *   60 Volt  10 Amp  NPN Darlington Transistor  06-28-1991
  83. **********
  84. .SUBCKT Q2N6649  1 2 3
  85. *    TERMINALS:  C B E
  86. Q1 1 2 4 QPWR .1
  87. Q2 1 4 3 QPWR
  88. R1 2 4  4K
  89. R2 4 3  50
  90. D1 1 3  DSUB
  91. .MODEL QPWR PNP (IS=12P NF=1 BF=49.3 VAF=139 IKF=7.5
  92. + ISE=21.2P NE=2 BR=4 NR=1 VAR=20 IKR=11.2 RE=.115 RB=.46
  93. + RC=46M XTB=1.5 CJE=2.21N CJC=481P TF=1.34P TR=3.67U)
  94. .MODEL DSUB D (IS=12P N=1 RS=.115 BV=60 IBV=.001
  95. + CJO=481P TT=3.67U)
  96. .ENDS
  97. *   60 Volt  10 Amp  PNP Darlington Transistor  06-28-1991
  98. .end
  99.